Hull
    name = "SH_ENDOSYMBIOTIC"
    description = "SH_ENDOSYMBIOTIC_DESC"
    speed = 100
    fuel = 2
    NoDefaultFuelEffect
    stealth = 25
    structure = 5
    slots = [
        Slot type = External position = (0.26, 0.45)
        Slot type = External position = (0.42, 0.45)
        Slot type = External position = (0.58, 0.45)
        Slot type = External position = (0.73, 0.45)
        Slot type = Internal position = (0.47, 0.68)
        Slot type = Internal position = (0.59, 0.68)
        Slot type = Internal position = (0.70, 0.68)
    ]
    buildcost = 25 * [[FLEET_UPKEEP_MULTIPLICATOR]] * [[SHIP_HULL_COST_MULTIPLIER]]
    buildtime = 6
    tags = [ "ORGANIC_HULL" "PEDIA_HULL_LINE_ORGANIC" "GOOD_FUEL_EFFICIENCY" ]
    location = And [
        Planet
        OwnedBy empire = Source.Owner
        Contains And [
            Building name = "BLD_SHIPYARD_ORG_CELL_GRO_CHAMB"
            OwnedBy empire = Source.Owner
        ]
        Contains And [
            Building name = "BLD_SHIPYARD_ORG_XENO_FAC"
            OwnedBy empire = Source.Owner
        ]
        Contains And [
            Building name = "BLD_SHIPYARD_ORG_ORB_INC"
            OwnedBy empire = Source.Owner
        ]
        Contains And [
            Building name = "BLD_SHIPYARD_BASE"
            OwnedBy empire = Source.Owner
        ]
    ]
    effectsgroups = [
        EffectsGroup
            scope = Source
            accountinglabel = "ORGANIC_GROWTH"
            effects = SetMaxStructure value = Value + ( min(Source.Age*0.5, 15)  * [[SHIP_STRUCTURE_FACTOR]] )

        [[GOOD_FUEL_EFFICIENCY]]
        [[ADD_HULL_FUEL_TO_MAX_FUEL_METER]]
        [[LIVING_HULL_EFFECTS_GROUPS]]
        [[SCAVANGE_FUEL_UNOWNED]]
        [[UNOWNED_GOOD_VISION]]
        [[UNOWNED_MOVE]]
    ]
    icon = "icons/ship_hulls/endosymbiotic_hull_small.png"
    graphic = "hulls_design/endosymbiotic_hull.png"

#include "organic.macros"

#include "../ship_hulls.macros"

#include "/scripting/common/upkeep.macros"
