Tech
    name = "SHP_REINFORCED_HULL"
    description = "SHP_REINFORCED_HULL_DESC"
    short_description = "STRUCTURE_SHORT_DESC"
    category = "SHIP_PARTS_CATEGORY"
    researchcost = 36 * [[TECH_COST_MULTIPLIER]]
    researchturns = 3
    tags = [ "PEDIA_DAMAGE_CONTROL_PART_TECHS" ]
    prerequisites = "CON_ARCH_MONOFILS"
    effectsgroups =
        EffectsGroup
            scope = And [
                Ship
                OwnedBy empire = Source.Owner
            ]
            effects = SetMaxStructure value = Value + 5
    graphic = "icons/tech/structural_integrity_fields.png"

Tech
    name = "SHP_BASIC_DAM_CONT"
    description = "SHP_BASIC_DAM_CONT_DESC"
    short_description = "STRUCTURE_SHORT_DESC"
    category = "SHIP_PARTS_CATEGORY"
    researchcost = 40 * [[TECH_COST_MULTIPLIER]]
    researchturns = 4
    tags = [ "PEDIA_DAMAGE_CONTROL_PART_TECHS" ]
    prerequisites = "SHP_MIL_ROBO_CONT"
    effectsgroups =
        EffectsGroup
            scope = And [
                Ship
                OwnedBy empire = Source.Owner
                Or [
                    Not InSystem
                    And [
                        InSystem
                        Turn low = LocalCandidate.System.LastTurnBattleHere + 1
                    ]
                ]
                Structure high = LocalCandidate.MaxStructure - 0.001
            ]
            effects = SetStructure value = Value + 1

Tech
    name = "SHP_FLEET_REPAIR"
    description = "SHP_FLEET_REPAIR_DESC"
    short_description = "SHIP_REPAIR_DESC"
    category = "SHIP_PARTS_CATEGORY"
    researchcost = 80 * [[TECH_COST_MULTIPLIER]]
    researchturns = 10
    tags = [ "PEDIA_DAMAGE_CONTROL_PART_TECHS" ]
    prerequisites = [
        "SHP_INTSTEL_LOG"
        "SHP_BASIC_DAM_CONT"
            ]
    effectsgroups =
        EffectsGroup
            scope = And [
                Ship
                InSystem
                Stationary
                OwnedBy empire = Source.Owner
                Turn low = LocalCandidate.System.LastTurnBattleHere + 1
                Structure high = LocalCandidate.MaxStructure - 0.001
                ResupplyableBy empire = Source.Owner
            ]
            effects = SetStructure value = Value + (Target.MaxStructure/10)

Tech
    name = "SHP_ADV_DAM_CONT"
    description = "SHP_ADV_DAM_CONT_DESC"
    short_description = "STRUCTURE_SHORT_DESC"
    category = "SHIP_PARTS_CATEGORY"
    researchcost = 100 * [[TECH_COST_MULTIPLIER]]
    researchturns = 5
    tags = [ "PEDIA_DAMAGE_CONTROL_PART_TECHS" ]
    prerequisites = [
        "SHP_FLEET_REPAIR"
        "CON_GAL_INFRA"
        ]
    effectsgroups =
        EffectsGroup
            scope = And [
                Ship
                OwnedBy empire = Source.Owner
                Stationary
                Turn low = LocalCandidate.System.LastTurnBattleHere + 1
            ]
            effects = SetStructure value = Value + (Target.MaxStructure/10)

#include "/scripting/common/base_prod.macros"
